Dynamiske effekter

Eksempler nedenfor viser forskellige måder at inkorporere dynamiske effekter på arbejdsudbuddet af skatter og offentlige udgifter i ADAM. De dynamiske effekter kan komme fra tre hovedkanaler; den ekstensive margin, den intensive margin og produktiviteten. Den ekstensive margin drejer sig om at deltage i arbejdsmarkedet - om en person søger arbejde eller ej. Den intensive margin på arbejdsudbuddet måler hvor meget der arbejdes. Derfor bliver den intensive margin først relevant, når det er valgt at deltage i arbejdsmarkedet via den ekstensive margin. Videre kan effekter på arbejdsudbuddet også komme igennem effekter på arbejdskraftens produktivitet. Typisk vil den dynamiske effekt af en skatteændring vedrøre arbejdsudbuddet, mens ændringer af offentlige udgifter både kan ændre arbejdsudbuddet og produktiviteten. Mere info om dynamiske effekter af skat og offentlige udgifter i ADAM kan findes i arbejdspapiret NNA010519, hvor også de nedenstående eksempler er hentet.

I det første eksempel reduceres topskatten med 0,86 pct.-point, og de dynamiske effekter inkluderes ved at øge aftalt arbejdstid Ha. Tallene for ændringer af aftalt arbejdstid er fra NNA010519, og repræsenterer at det er 44 arbejdsuger pr. år, 1,0182 er forholdet mellem ny og gammel marginalskattesats og 405 er det antal personer (i 1000) som antages at blive berørt af skatteændringen. Det forudsættes at der er 37 arbejdstimer om ugen, og en arbejdsudbudselasticitet på 0,1 mht. timeløn efter skat. Dvs. at en skatteændring, der øger den reale timeløn efter skat med 1 pct., vil derved øge arbejdstiden i timer med 0,1 pct. Marginallønnen regnes som elasticiteten ganget med antal arbejdstimer, som med antagelsen om en elasticitet på 0,1 og en ugentlig arbejdstid på 37 timer, giver 3,7 timer ekstra om ugen.

  READ lang19 ;
  TIME 2019 2060;
  SERIES tsysp2 = @tsysp2 - 0.0086;
  SERIES ha = @ha + (44*3.7*Log(1.0182))*405/Q;
  SIM;

Det næste eksempel ser på forbedret normering i dagsinstitutioner, hvor der ansættes 6400 personer i dagsinsitutioner for at reducere antal børn per voksen. I tillæg ændres korrektionsfaktoren, klo1, for den relative gennemsnitlige timeløn i den offentlige sektor relativt til timelønnen i industrien. I udtrykket for ændringen i klo1, indgår antal ansatte i offentlig sektor Qo1, og tallet 0.7 kommer fra antagelsen om at de 6400 personer, som skal ansættes, skal have gennemsnitlig løn, som svarer til ca 70 pct. af den gennemsnitlige løn i den offentlige sektor. Videre antages det at 750 mio. kr. af udgiftene skal dækkes ved brugerbetaling, og resten af udgiftene er i offentligt forbrug. Den gennemsnitlige arbejdstid i vuggestuer er relativt lav, og derfor reduceres også hgo1 og hgwo en smule. Ændringen i produktionen trækker automatisk en række andre ændringer med sig, som der korrigeres for ved at sænke effekterne på materialeinputtet i daginstitutionerne. Det gøres ved at reducere fVeo1 og fVmo1. De dynamiske effekter lægges både på den ekstensive og den intensive margin. På den ekstensive margin, reduceres antallet af personer uden for arbejdsmarkedet, Uq, med 250 personer. På den intensive margin øges aftalt arbejdstid, ved at forældres andel af den samlede beskæftigelse (70600 personer/Q) øges med 0,63 pct., som er den beregnede stigning i forældres arbejdsindsats målt i fuldtidsbeskæftigelse.

  READ lang19 ;
  TIME 2019 2031;
  SERIES dco=0;
  SERIES zqo1 = zqo1+6.4;
  SERIES klo1 = klo1*(1*Qo1/(6.4+Qo1)+0.8*6.4/(6.4+Qo1));
  SERIES <2019 2019> JRhgo1 = -0.000012;
  SERIES <2019 2019> JRhgwo = -0.000012;
  SERIES <2019 2019> JRfVeo1 + -0.0045 ;
  SERIES <2019 2019> JRfVmo1 + -0.0045 ;
  SERIES <2019 2019> JDaxo_cs = @JDaxo_cs + 750/(fCs*pxo_p) ;
  SERIES Ha = (1+(70.6/Q)*0.0063)*Ha;
  SERIES Uq = Uq - 0.25;
  SIM;
  EXO fXo1_p;
  ENDO JDfXo1_p;
  SERIES fXo1_p = @fXo1_p + (fXo_p - @fXo_p);
  SIM;
  UNFIX;

Det næste eksempel bygger på det foregående, hvor der nu skal være balance på de offentlige finanser. Fx. kan ansættelsen af pædagogerne finansieres med en forøgelse af bundskatten. Som vist i første eksempel, så vil en skattestigning have negative dynamiske effekter, som også kan medregnes. Givet at omkostningerne ved ansættelsen af pædagogerne er 3325 mia. kr., må bundskatten øges med 3325/@Ysp1[2019], hvor Ysp1 er udskrivningsgrundlaget for bundskatten. Videre lægges det til en negativ effekt på aftalt arbejdstid, baseret på antagelsen om der er en elasticitet på 0,1 mellem disponibel indkomst og skattesats, og at skattesatsen ændres som beskrevet (se s. 17 i NNA010519).

  READ lang19 ;
  TIME 2019 2060;
  SERIES dco=0;
  SERIES zqo1 = zqo1+6.4;
  SERIES klo1 = klo1*(1*Qo1/(6.4+Qo1)+0.7*6.4/(6.4+Qo1));
  SERIES <2019 2019> JRhgo1 = -0.000012;
  SERIES <2019 2019> JRhgwo = -0.000012;
  SERIES <2019 2019> JRfVeo1 + -0.0045 ;
  SERIES <2019 2019> JRfVmo1 + -0.0045 ;
  SERIES <2019 2019> JDaxo_cs = @JDaxo_cs + 750/(fCs*pxo_p) ;
  SERIES tsysp1 = @tsysp1 + 3325/@Ysp1[2019];
  SERIES Ha = (1+(70.6/Q)*0.0063)*Ha;
  SERIES Uq = Uq - 0.25;
  SERIES Ha = Ha - 0.00557*@Ha;
  SIM;
  EXO fXo1_p;
  ENDO JDfXo1_p;
  SERIES fXo1_p = @fXo1_p + (fXo_p - @fXo_p);
  SIM;
  UNFIX;

Det sidste eksempel ser på forbedret uddannelsesniveau og mulige dynamiske effekter på arbejdsudbuddet. Her øges derfor antallet af personer med en mellemlang videregående uddannelse med 500 personer over 3 år. Det gøres ved at øge antallet af personer der modtager SU, Usu, med 500 personer i de tre år, hvor de uddannes. Tilsvarende øges antallet af uddannelsessøgende udenfor arbejdsstyrken, Uuxa, med 500 personer. Desuden øges den offentlige beskæftigelse med 68 personer (lærerstab mv.) i de tre år. De dynamiske effekter lægges til fra 2022, når de 500 personer er færdiguddannede, og varer til 2059, hvor de 500 antages at forlade arbejdsmarkedet. Den aftalte arbejdstid, hak, øges mht. en forudsætning om at arbejdstiden øger med 11.5 timer pr. år for de 500 ekstra personer, der fuldfører en mellemlang videregående uddannelse. Desuden antages det at effekten kun slår igennem med 1/3. I tillæg øges produktiviteten ved at øge effektivitetstrenden for arbejdskraft i de forskellige ADAM-brancher, samlet i dtl{i}'erne. Her øges produktiviteten med 27.4 pct. for de 500 personer, med antagelsen om effekten slår igennem med 2/3. For resten af de beskæftigede, antages det at produktiviteten er uændret. Videre forudsættes det at arbejdsstyrken langsigtig øges med ca 25 personer, eller ca. ½ person årligt. Derfor reduceres residualgruppen af personer uden for arbejdsmarkedet, Uq. Endvidere reduceres også den strukturelle ledighed, bulbw .

  READ lang19 ;
  TIME 2019 2060;
  SERIES <2019 2021> Usu + 0.5;
  SERIES <2019 2021> Uuxa + 0.5;
  SERIES <2019 2021> zQo1 + 0.06;
  SERIES <2022 2059> JHak = @jhak + 11.5*0.5+(1-0.66)/Q;
  SERIES <2022 2059> Uq = @Uq - (tid-2018)*0.0006098;
  SERIES <2022 2059> Jbulbw + -0.000001;
  FOR i =o1,a,b,e,h,ne,nf,ng,nz,qf,qs,qz;
   SERIES <2022 2059> dtl{i} = @dtl{i}*(1.274*0.5*0.66 + 1*(Q-0.5*0.66))/Q;
  END;
  SIM;